SharePoint.Files

Sintaxis

SharePoint.Files(url as text, optional options as nullable record) as table

Acerca de

Devuelve una tabla que contiene una fila para cada archivo que se encuentra en el sitio de SharePoint especificado, , urlincluidos los archivos de las subcarpetas. A diferencia SharePoint.Contentsde , esta función devuelve una tabla plana y no incluye filas para carpetas. La dirección URL del sitio no puede contener una cadena de consulta ni un fragmento. Cada fila contiene el contenido binario del archivo en la Content columna y los metadatos de archivo de las Namecolumnas , , ExtensionDate modifiedDate accessed, , Date created, Attributesy .Folder Path El Folder Path valor es la dirección URL absoluta de la carpeta que contiene el archivo. options se puede especificar para controlar las siguientes opciones:

• ApiVersion: un número (14 o 15) o el texto "Automático" que especifica la versión de la API de SharePoint que se va a usar para este sitio. Cuando no se especifica, se usa la versión 14 de la API. Cuando se especifica Auto, la versión del servidor se detectará automáticamente si es posible; de lo contrario, la versión tiene como valor predeterminado 14. Los sitios de SharePoint que no son en inglés requieren al menos la versión 15.

Ejemplo 1

Enumere el nombre, la extensión de archivo y la dirección URL de carpeta de cada archivo del sitio de Contoso SharePoint mediante la selección automática de API.

Uso

let
    Source = SharePoint.Files(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = "Auto"]
    ),
    SelectedColumns = Table.SelectColumns(
        Source,
        {"Name", "Extension", "Folder Path"}
    )
in
    SelectedColumns

Output

A table containing the name, extension, and absolute folder URL for each file in the site and its subfolders.

Ejemplo 2

Devuelve todos los archivos con la .xlsx extensión del sitio de SharePoint contoso. En este ejemplo se usa la versión 15 de la API, que funciona con sitios de SharePoint inglés y no inglés. La comparación de extensiones no distingue mayúsculas de minúsculas, por lo que también coincide con .XLSX.

Uso

let
    Source = SharePoint.Files(
        "https://contoso.sharepoint.com/sites/Contoso",
        [ApiVersion = 15]
    ),
    ExcelWorkbooks = Table.SelectRows(
      Source,
      each Comparer.OrdinalIgnoreCase([Extension], ".xlsx") = 0
    )
  in
    ExcelWorkbooks

Output

A table containing every .xlsx file in the site and its subfolders.

Ejemplo 3

Devuelve solo los archivos almacenados directamente en la Shared Documents/Reports carpeta . Una coincidencia exacta Folder Path excluye los archivos de las subcarpetas.

Uso

let
    Source = SharePoint.Files("https://contoso.sharepoint.com/sites/Contoso"),
    ReportsFiles = Table.SelectRows(
        Source,
        each [Folder Path] = "https://contoso.sharepoint.com/sites/Contoso/Shared Documents/Reports/"
    )
in
    ReportsFiles

Output

A table containing only the files stored directly in the Reports folder.

Ejemplo 4

Devuelve el contenido binario de Budget.xlsx de la carpeta Documentos/informes compartidos.

Uso

let
    Source = SharePoint.Files("https://contoso.sharepoint.com/sites/Contoso"),
    Budget = Source{
      [
        Name = "Budget.xlsx",
        #"Folder Path" = "https://contoso.sharepoint.com/sites/Contoso/Shared Documents/Reports/"
      ]
    }[Content]
  in
    Budget

Output

The binary content of Budget.xlsx.