Financial.FV(Double, Double, Double, Double, DueDate) Metodo

Definizione

Spazio dei nomi:
Microsoft.VisualBasic
Assembly:
Microsoft.VisualBasic.dll

Restituisce un valore che specifica il valore futuro di un'annualità in base a pagamenti periodici fissi e a un tasso di interesse fisso.

public static double FV(double Rate, double NPer, double Pmt, double PV = 0, Microsoft.VisualBasic.DueDate Due = Microsoft.VisualBasic.DueDate.EndOfPeriod);
static member FV : double * double * double * double * Microsoft.VisualBasic.DueDate -> double
Public Function FV (Rate As Double, NPer As Double, Pmt As Double, Optional PV As Double = 0, Optional Due As DueDate = Microsoft.VisualBasic.DueDate.EndOfPeriod) As Double

Parametri

Rate
Double

Required. Tasso di interesse per periodo. Ad esempio, se si ottiene un prestito per l'auto a un tasso percentuale annuo del 10% e si effettuano pagamenti mensili, il tasso di interesse per periodo è 0,1/12 o 0,0083.

NPer
Double

Required. Numero totale di periodi di pagamento nell'annualità. Ad esempio, se si effettuano pagamenti mensili per un prestito di quattro anni di auto, il prestito ha un totale di 4 x 12 (o 48) periodi di pagamento.

Pmt
Double

Required. Pagamento da effettuare per ogni periodo. I pagamenti in genere contengono una quota di capitale e una quota di interesse che non cambiano nel corso della durata dell'annualità.

PV
Double

Optional. Valore attuale (o somma capitale) di una serie di pagamenti futuri. Ad esempio, quando si prende in prestito del denaro per acquistare un'auto, l'importo del prestito è il valore attuale per il prestatore dei pagamenti mensili dell'auto da effettuare. Se omesso, viene usato il valore 0.

Due
DueDate

Optional. Oggetto di tipo DueDate che specifica quando sono in scadenza i pagamenti. Questo argomento deve essere DueDate.EndOfPeriod se i pagamenti sono dovuti alla fine del periodo di pagamento o DueDate.BegOfPeriod se i pagamenti sono dovuti all'inizio del periodo. Se omesso, DueDate.EndOfPeriod si presuppone .

Valori restituiti

Double

Il valore futuro di un'annualità in base a pagamenti periodici fissi e a un tasso di interesse fisso.

Esempio

In questo esempio viene utilizzata la FV funzione per restituire il valore futuro di un investimento in base al tasso percentuale che accumula per periodo (APR / 12), il numero totale di pagamenti (), il pagamento (TotPmtsPayment), il valore corrente dell'investimento (PVal) e un numero che indica se il pagamento viene effettuato all'inizio o alla fine del periodo di pagamento (PayType). Si noti che poiché Payment rappresenta il pagamento in contanti, si tratta di un numero negativo.

Sub TestFV()
    Dim TotPmts As Integer
    Dim Payment, APR, PVal, Fval As Double
    Dim PayType As DueDate
    Dim Response As MsgBoxResult

    ' Define money format.
    Dim Fmt As String = "###,###,##0.00"
    Payment = CDbl(InputBox("How much do you plan to save each month?"))
    APR = CDbl(InputBox("Enter the expected interest annual percentage rate."))
    ' Ensure proper form.
    If APR > 1 Then APR = APR / 100
    TotPmts = CInt(InputBox("For how many months do you expect to save?"))
    Response = MsgBox("Do you make payments at the end of month?", MsgBoxStyle.YesNo)
    If Response = MsgBoxResult.No Then
        PayType = DueDate.BegOfPeriod
    Else
        PayType = DueDate.EndOfPeriod
    End If
    PVal = CDbl(InputBox("How much is in this savings account now?"))
    Fval = FV(APR / 12, TotPmts, -Payment, -PVal, PayType)
    MsgBox("Your savings will be worth " & Format(Fval, Fmt) & ".")
End Sub

Commenti

Un'annualità è una serie di pagamenti in contanti fissi effettuati nel tempo. Può essere un prestito (ad esempio un mutuo per la casa) o un investimento (ad esempio un piano di risparmio mensile).

Gli Rate argomenti e NPer devono essere calcolati utilizzando periodi di pagamento espressi nelle stesse unità. Ad esempio, se Rate viene calcolato utilizzando mesi, NPer è necessario calcolare anche i mesi.

In tutti gli argomenti, gli esborsi in contanti, come i depositi versati su un conto di risparmio, sono rappresentati da numeri negativi, mentre le somme in contanti incassate, come i dividendi, sono rappresentate da numeri positivi.

Si applica a

Vedi anche