Clock.TickCount Eigenschap

public:
 property int TickCount { int get(); };

public int TickCount { get; }

member this.TickCount : int

Public ReadOnly Property TickCount As Integer

Waarde van eigenschap

Een Integer met het aantal milliseconden van de systeemtimer van de computer.

Voorbeelden

In het volgende voorbeeld wordt de My.Computer.Clock.TickCount eigenschap gebruikt om een taak gedurende een bepaald aantal seconden uit te voeren in een lus, zelfs als de systeemtijd van de computer verandert terwijl deze wordt uitgevoerd.

Public Sub LoopTask(ByVal secondsToRun As Integer)
    Dim startTicks As Integer = My.Computer.Clock.TickCount
    Do While IsTimeUp(startTicks, secondsToRun)
        ' Code to run for at least secondsToRun seconds goes here.
    Loop
End Sub

Private Function IsTimeUp(
    ByVal startTicks As Integer,
    ByVal seconds As Integer
) As Boolean
    ' This function throws an overflow exception if the
    ' tick count difference is greater than 2,147,483,647,  
    ' about 24 days for My.Computer.Clock.TickCount.

    ' Use UInteger to simplify the code for roll over.
    Dim uStart As UInteger =
        CUInt(CLng(startTicks) - Integer.MinValue)
    Dim uCurrent As UInteger =
        CUInt(CLng(My.Computer.Clock.TickCount) - Integer.MinValue)

    ' Calculate the tick count difference.
    Dim tickCountDifference As UInteger
    If uStart <= uCurrent Then
        tickCountDifference = uCurrent - uStart
    Else
        ' Tick count rolled over.
        tickCountDifference = UInteger.MaxValue - (uStart - uCurrent)
    End If

    ' Convert seconds to milliseconds and compare.
    Return CInt(tickCountDifference) < (seconds * 1000)
End Function

Opmerkingen

De TickCount eigenschap biedt toegang tot de systeemtimer van de computer, die wordt uitgevoerd wanneer de computer actief is. De timerresolutie is niet minder dan 500 milliseconden.

U kunt deze eigenschap gebruiken om het gedrag van uw toepassing afhankelijk te maken van de tijdsduur waarop deze wordt uitgevoerd, of u kunt deze gebruiken om gebeurtenissen te labelen, die beide onafhankelijk zijn van de klok van de computer.

Als de computer continu wordt uitgevoerd, TickCount wordt het in ongeveer 24,9 dagen verhoogd van nul naar de maximumwaarde voor gehele getallen.

De TickCount eigenschap wordt alleen verhoogd wanneer het besturingssysteem wordt uitgevoerd. Deze pauzeert wanneer de computer in bepaalde energiebesparende modi gaat, zoals stand-by of sluimerstand. De TickCount eigenschap is niet gerelateerd aan de klokinstelling van de computer.

Gebruik de LocalTime eigenschap of GmtTime eigenschap om de huidige lokale datum en tijd op deze computer te verkrijgen.

De My.Computer.Clock.TickCount eigenschap heeft hetzelfde gedrag als de Environment.TickCount eigenschap.

Beschikbaarheid per projecttype

Zie ook

• TickCount
• Objects (Visual Basic)