ErrObject.LastDllError Eigenschap

public:
 property int LastDllError { int get(); };

public int LastDllError { get; }

public int LastDllError { [System.Security.SecurityCritical] get; }

member this.LastDllError : int

[<get: System.Security.SecurityCritical>]
member this.LastDllError : int

Public ReadOnly Property LastDllError As Integer

Waarde van eigenschap

Een systeemfoutcode die wordt geproduceerd door een aanroep naar een DLL (Dynamic Link Library).

Kenmerken

SecurityCriticalAttribute

Voorbeelden

In het volgende voorbeeld ziet u hoe u de eigenschap LastDllError kunt gebruiken nadat u een functie hebt aangeroepen in de Windows-API. De PrintWindowCoordinates procedure neemt een ingang naar een venster en roept de GetWindowRect functie aan. GetWindowRect vult de RECT-gegevensstructuur met de lengten van de zijden van de rechthoek waaruit het venster bestaat. Als u een ongeldige ingang doorgeeft, treedt er een fout op en is het foutnummer beschikbaar via de LastDllError eigenschap.

Declare Function GetWindowRect Lib "user32" (
    ByVal hwnd As Integer, ByRef lpRect As RECT) As Integer

Public Structure RECT
    Public Left As Integer
    Public Top As Integer
    Public Right As Integer
    Public Bottom As Integer
End Structure

Const ERROR_INVALID_WINDOW_HANDLE As Long = 1400
Const ERROR_INVALID_WINDOW_HANDLE_DESCR As String = 
    "Invalid window handle."

Private Sub PrintWindowCoordinates(ByVal hwnd As Integer)
' Prints left, right, top, and bottom positions
' of a window in pixels.

  Dim rectWindow As RECT

  ' Pass in window handle and empty the data structure.
  ' If function returns 0, an error occurred.
  If GetWindowRect(hwnd, rectWindow) = 0 Then
      ' Check LastDllError and display a dialog box if the error
      ' occurred because an invalid handle was passed.
      If Err.LastDllError = ERROR_INVALID_WINDOW_HANDLE Then
          MsgBox(ERROR_INVALID_WINDOW_HANDLE_DESCR, Title:="Error!")
      End If
  Else
      Debug.Print(rectWindow.Bottom)
      Debug.Print(rectWindow.Left)
      Debug.Print(rectWindow.Right)
      Debug.Print(rectWindow.Top)
  End If
End Sub

Opmerkingen

De eigenschap LastDllError is alleen van toepassing op DLL-aanroepen van Visual Basic code. Wanneer een dergelijke aanroep wordt gedaan, retourneert de aangeroepen functie meestal een code die aangeeft dat het gelukt of mislukt is en de LastDllError eigenschap wordt ingevuld. Raadpleeg de documentatie voor de functies van het DLL-bestand om de retourwaarden te bepalen die duiden op slagen of mislukken. Wanneer de foutcode wordt geretourneerd, moet de Visual Basic toepassing onmiddellijk de eigenschap LastDllError controleren. Er wordt geen uitzondering gegenereerd wanneer de LastDllError eigenschap is ingesteld.

Zie ook

• Err()
• ErrorToString()