Strings.Format(Object, String) Methode

public static string Format(object Expression, string Style = "");

static member Format : obj * string -> string

Public Function Format (Expression As Object, Optional Style As String = "") As String

Parameters

Retouren

Een tekenreeks die is opgemaakt volgens de instructies in een notatie-expressie String .

Voorbeelden

In dit voorbeeld ziet u verschillende toepassingen van de functie voor het Format opmaken van waarden met zowel String indelingen als door de gebruiker gedefinieerde indelingen. Voor het datumscheidingsteken (), het tijdscheidingsteken (/:) en de AM/PM-indicatoren (tentt), is de werkelijke opgemaakte uitvoer die door uw systeem wordt weergegeven, afhankelijk van de landinstellingen die de code gebruikt. Wanneer tijden en datums worden weergegeven in de ontwikkelomgeving, worden de korte tijdnotatie en de korte datumnotatie van de landinstelling van de code gebruikt.

Dim testDateTime As Date = #1/27/2001 5:04:23 PM#
Dim testStr As String
' Returns current system time in the system-defined long time format.
testStr = Format(Now(), "Long Time")
' Returns current system date in the system-defined long date format.
testStr = Format(Now(), "Long Date")
' Also returns current system date in the system-defined long date 
' format, using the single letter code for the format.
testStr = Format(Now(), "D")

' Returns the value of testDateTime in user-defined date/time formats.
' Returns "5:4:23".
testStr = Format(testDateTime, "h:m:s")
' Returns "05:04:23 PM".
testStr = Format(testDateTime, "hh:mm:ss tt")
' Returns "Saturday, Jan 27 2001".
testStr = Format(testDateTime, "dddd, MMM d yyyy")
' Returns "17:04:23".
testStr = Format(testDateTime, "HH:mm:ss")
' Returns "23".
testStr = Format(23)

' User-defined numeric formats.
' Returns "5,459.40".
testStr = Format(5459.4, "##,##0.00")
' Returns "334.90".
testStr = Format(334.9, "###0.00")
' Returns "500.00%".
testStr = Format(5, "0.00%")

Opmerkingen

De String.Format methode biedt ook vergelijkbare functionaliteit.

Als u een niet-gelokaliseerde numerieke tekenreeks opmaakt, moet u een door de gebruiker gedefinieerde numerieke notatie gebruiken om ervoor te zorgen dat u het gewenste uiterlijk krijgt.

Als u een getal probeert op te maken zonder op te Stylegeven, biedt de Format functie functionaliteit die vergelijkbaar is met de Str functie, hoewel deze internationaal op de hoogte is. Positieve getallen die zijn opgemaakt als tekenreeksen met behulp van de Format functie bevatten echter geen voorloopruimte die is gereserveerd voor het teken van de waarde. De getallen die zijn geconverteerd met behulp van de Str functie behouden de voorloopruimte.

Verschillende notaties voor verschillende numerieke waarden

Een door de gebruiker gedefinieerde notatie-expressie voor getallen kan bestaan uit één tot drie secties, gescheiden door puntkomma's. Als het Style argument van de Format functie een van de vooraf gedefinieerde numerieke notaties bevat, is slechts één sectie toegestaan.

Als u	Dit is het resultaat
Slechts één sectie	De notatie-expressie is van toepassing op alle waarden.
Twee secties	De eerste sectie is van toepassing op positieve waarden en nullen; de tweede is van toepassing op negatieve waarden.
Drie secties	De eerste sectie is van toepassing op positieve waarden, de tweede is van toepassing op negatieve waarden en de derde is van toepassing op nullen.

Het volgende voorbeeld bevat twee secties: de eerste definieert de notatie voor positieve waarden en nullen; de tweede sectie definieert de notatie voor negatieve waarden. Omdat het Style argument van de Format functie een tekenreeks gebruikt, wordt deze tussen aanhalingstekens geplaatst.

Dim style1 As String = "$#,##0;($#,##0)"

Als u puntkomma's met niets ertussen opneemt, wordt de ontbrekende sectie afgedrukt met behulp van de notatie van de positieve waarde. In de volgende notatie worden bijvoorbeeld positieve en negatieve waarden weergegeven met behulp van de notatie in de eerste sectie en wordt weergegeven Zero of de waarde nul is.

Dim style2 As String = "$#,##0;;\Z\e\r\o"

Vooraf gedefinieerde numerieke notaties

In de volgende tabel worden de vooraf gedefinieerde namen van numerieke notaties geïdentificeerd. Deze kunnen worden gebruikt met de naam als het Style argument voor de Format functie:

Indelingsnaam	Beschrijving
General Number, Gof g	Geeft een getal weer zonder scheidingsteken voor duizendtallen. Bijvoorbeeld, Format(&H3FA, "g") retourneert 1018.
Currency, Cof c	Geeft het getal weer met scheidingsteken voor duizendtallen, indien van toepassing; geeft twee cijfers rechts van het decimaalteken weer. Uitvoer is gebaseerd op de landinstellingen van het systeem. Bijvoorbeeld, Format(1234567, "c") retourneert $1,234,567.00.
Fixed, Fof f	Geeft ten minste één cijfer links weer en twee cijfers rechts van het decimaalteken. Bijvoorbeeld, Format(1234567, "f") retourneert 1234567.00.
Standard, Nof n	Geeft het getal weer met scheidingsteken voor duizendtallen, ten minste één cijfer links en twee cijfers rechts van het decimaalteken. Bijvoorbeeld, Format(1234567, "n") retourneert 1,234,567.00.
Percent	Geeft het getal weer vermenigvuldigd met 100 met een procentteken (%) direct aan de rechterkant toegevoegd; geeft altijd twee cijfers rechts van het decimaalteken weer. Bijvoorbeeld, Format(0.4744, "Percent") retourneert 47.44%.
P, of p	Geeft het getal weer met scheidingsteken voor duizendtallen vermenigvuldigd met 100 met een procentteken (%) toegevoegd aan de rechterkant en gescheiden door één spatie; geeft altijd twee cijfers rechts van het decimaalteken weer. Bijvoorbeeld, Format(0.80345, "p") retourneert 80.35 %.
Scientific	Maakt gebruik van standaard wetenschappelijke notatie, met twee significante cijfers. Bijvoorbeeld, Format(1234567, "Scientific") retourneert 1.23E+06.
E, of e	Maakt gebruik van standaard wetenschappelijke notatie, met zes significante cijfers. Bijvoorbeeld, Format(1234567, "e") retourneert 1.234567e+006.
D, of d	Geeft een getal weer als een tekenreeks die de waarde van het getal in de notatie Decimaal (grondtal 10) bevat. Deze optie wordt alleen ondersteund voor integrale typen (Byte, Short, Integer, Long) . Bijvoorbeeld, Format(&H7F, "d") retourneert 127.
X, of x	Geeft een getal weer als een tekenreeks die de waarde van het getal in hexadecimale notatie (basis 16) bevat. Deze optie wordt alleen ondersteund voor integrale typen (Byte, Short, Integer, Long) . Bijvoorbeeld, Format(127, "x") retourneert 7f.
Yes/No	Geeft weer No of getal 0 is; anders wordt weergegeven Yes. Bijvoorbeeld, Format(0, "Yes/No") retourneert No.
True/False	Geeft weer False of getal 0 is; anders wordt weergegeven True. Bijvoorbeeld, Format(1, "True/False") retourneert True.
On/Off	Geeft weer Off of getal 0 is; anders wordt weergegeven On. Bijvoorbeeld, Format(1, "On/Off") retourneert On.

Opmerkingen bij ontwikkelaars van slimme apparaten

De Yes/Noindelingen , True/Falseen On/Off indelingen worden niet ondersteund.

User-Defined numerieke notaties

De volgende tabel bevat tekens die u kunt gebruiken om door de gebruiker gedefinieerde getalnotaties te maken. Deze kunnen worden gebruikt om het Style argument voor de Format functie te maken:

Teken	Beschrijving
Geen	Geeft het getal weer zonder opmaak.
(0)	Plaatsaanduiding voor cijfer. Geeft een cijfer of een nul weer. Als de expressie een cijfer heeft op de positie waar de nul wordt weergegeven in de notatietekenreeks, geeft u deze weer; anders wordt een nul op die positie weergegeven. Als het getal minder cijfers heeft dan nullen (aan beide zijden van het decimaalteken) in de notatie-expressie, worden voorloopnullen of volgnullen weergegeven. Als het getal meer cijfers rechts van het decimaalteken heeft dan nullen rechts van het decimaalteken in de notatie-expressie, rondt u het getal af op zoveel decimalen als er nullen zijn. Als het getal links van het decimaalteken meer cijfers bevat dan er nullen links van het decimaalteken in de notatie-expressie staan, worden de extra cijfers zonder wijziging weergegeven.
(#)	Plaatsaanduiding voor cijfer. Geeft een cijfer of niets weer. Als de expressie een cijfer heeft op de positie waar het # teken wordt weergegeven in de notatietekenreeks, wordt deze weergegeven. Anders wordt er niets op die positie weergegeven. Dit symbool werkt net als de 0 tijdelijke aanduiding voor cijfers, behalve dat voorloop- en volgnullen niet worden weergegeven als het getal minder cijfers heeft # dan aan beide zijden van het decimaalteken in de notatie-expressie.
(.)	Tijdelijke aanduiding voor decimalen. De tijdelijke aanduiding voor decimalen bepaalt hoeveel cijfers links en rechts van het decimaalteken worden weergegeven. Als de notatie-expressie alleen # tekens links van dit symbool bevat; getallen kleiner dan 1 beginnen met een decimaalteken. Als u een voorloopnul wilt weergeven die wordt weergegeven met breukgetallen, gebruikt u nul als tijdelijke aanduiding voor het eerste cijfer links van het decimaalteken. In sommige landen of regio's wordt een komma gebruikt als het decimaalteken. Het werkelijke teken dat wordt gebruikt als een tijdelijke aanduiding voor decimalen in de opgemaakte uitvoer, is afhankelijk van de getalnotatie die door uw systeem wordt herkend. U moet de punt dus gebruiken als de tijdelijke aanduiding voor decimalen in uw notaties, zelfs als u zich in een landinstelling bevindt die een komma gebruikt als een tijdelijke aanduiding voor decimalen. De opgemaakte tekenreeks wordt weergegeven in de juiste notatie voor de landinstelling.
(%)	Tijdelijke aanduiding voor percentage. Vermenigvuldigt de expressie met 100. Het procentteken (%) wordt ingevoegd op de positie waar het wordt weergegeven in de notatietekenreeks.
(,)	Scheidingsteken voor duizendtallen. Het scheidingsteken voor duizendtallen scheidt duizenden van honderden binnen een getal met vier of meer posities links van het decimaalteken. Standaardgebruik van het scheidingsteken voor duizendtallen wordt opgegeven als de notatie een scheidingsteken voor duizendtallen bevat dat wordt omgeven door tijdelijke aanduidingen voor cijfers (0 of #). Een scheidingsteken voor duizendtallen direct links van het decimaalteken (ongeacht of er al dan niet een decimaalteken is opgegeven) of als het meest rechtse teken in de tekenreeks betekent dat het getal wordt geschaald door het te delen door 1000, indien nodig af te ronden. Getallen kleiner dan 1000, maar groter of gelijk aan 500 worden weergegeven als 1, en getallen kleiner dan 500 worden weergegeven als 0. Twee aangrenzende scheidingstekens voor duizendtallen in deze positieschaal met een factor van 1 miljoen en een extra factor van 1000 voor elk extra scheidingsteken. Meerdere scheidingstekens in een andere positie dan direct links van het decimaalteken of de meest rechtse positie in de tekenreeks worden behandeld als het opgeven van het gebruik van een scheidingsteken voor duizendtallen. In sommige landinstellingen wordt een periode gebruikt als scheidingsteken voor duizendtallen. Het werkelijke teken dat wordt gebruikt als scheidingsteken voor duizendtallen in de opgemaakte uitvoer, is afhankelijk van de getalnotatie die door uw systeem wordt herkend. Gebruik de komma dus als scheidingsteken voor duizendtallen in uw notaties, zelfs als u zich in een landinstelling bevindt die een punt als scheidingsteken voor duizendtallen gebruikt. De opgemaakte tekenreeks wordt weergegeven in de juiste notatie voor de landinstelling. Denk bijvoorbeeld aan de drie volgende notatietekenreeksen: - "#,0.", dat het scheidingsteken voor duizendtallen gebruikt om het getal 100 miljoen op te maken als de tekenreeks "100.000.000". - "#0,.", waarbij schaalaanpassing wordt gebruikt met een factor van duizend om het getal 100 miljoen op te maken als de tekenreeks "100000". - "#,0,.", waarbij het scheidingsteken voor duizendtallen wordt gebruikt en met duizend wordt geschaald om het getal 100 miljoen op te maken als tekenreeks "100.000".
(:)	Tijdscheidingsteken. In sommige landinstellingen kunnen andere tekens worden gebruikt om het tijdscheidingsteken weer te geven. Het tijdscheidingsteken scheidt uren, minuten en seconden wanneer tijdwaarden zijn opgemaakt. Het werkelijke teken dat wordt gebruikt als tijdscheidingsteken in opgemaakte uitvoer, wordt bepaald door uw systeeminstellingen.
(/)	Datumscheidingsteken. In sommige landinstellingen kunnen andere tekens worden gebruikt om het datumscheidingsteken weer te geven. Het datumscheidingsteken scheidt de datum, maand en het jaar waarop datumwaarden zijn opgemaakt. Het werkelijke teken dat wordt gebruikt als het datumscheidingsteken in opgemaakte uitvoer, wordt bepaald door de systeeminstellingen.
(E-``E+``e-``e+)	Wetenschappelijke notatie. Als de notatie-expressie ten minste één tijdelijke aanduiding voor cijfers (0 of #) links van E-, E+, e-of , of e+, bevat, wordt het getal weergegeven in wetenschappelijke notatie en E of e wordt ingevoegd tussen het getal en de exponent. Het aantal tijdelijke aanduidingen voor cijfers links bepaalt het aantal cijfers in de exponent. Gebruik E- of e- plaats een minteken naast negatieve exponenten. Gebruik E+ of e+ plaats een minteken naast negatieve exponenten en een plusteken naast positieve exponenten. U moet ook tijdelijke aanduidingen voor cijfers rechts van dit symbool opnemen om de juiste opmaak te krijgen.
- + $ ( )	Letterlijke tekens. Deze tekens worden exact weergegeven zoals getypt in de notatietekenreeks. Als u een ander teken dan een van de vermelde tekens wilt weergeven, plaatst u een backslash (\) of plaatst u het tussen dubbele aanhalingstekens (" ").
(\)	Geeft het volgende teken weer in de notatietekenreeks. Als u een teken met een speciale betekenis als een letterlijk teken wilt weergeven, moet u er een backslash (\) aan toevoegen. De backslash zelf wordt niet weergegeven. Het gebruik van een backslash is hetzelfde als het plaatsen van het volgende teken tussen dubbele aanhalingstekens. Als u een backslash wilt weergeven, gebruikt u twee backslashes (\\). Voorbeelden van tekens die niet als letterlijke tekens kunnen worden weergegeven, zijn de tekens voor datumopmaak en tijdnotatie (tekens dcqtysnmhp/wvoor tekenreeksopmaak ,a en :), de tekens voor numerieke opmaak (#, 0, %, , Ekomma een punt) en de tekenreeksopmaaktekens (@, <&>en ).!
("``ABC``")	Geeft de tekenreeks weer tussen de dubbele aanhalingstekens (" "). Als u een tekenreeks wilt opnemen in het stijlargument vanuit code, moet Chr(34) u de tekst insluiten (34 is de tekencode voor een aanhalingsteken (")).

Voorbeeld van verouderde code

De volgende tabel bevat enkele voorbeelden van notatie-expressies voor getallen. (In deze voorbeelden wordt ervan uitgegaan dat de landinstelling van uw systeem Engels-V.S.) De eerste kolom bevat de notatietekenreeksen voor het Style argument van de Format functie. De andere kolommen bevatten de resulterende uitvoer als de opgemaakte gegevens de waarde in de kolomkoppen hebben.

Opmaak (Style)	"5" opgemaakt als	"-5" opgemaakt als	"0.5" opgemaakt als
Zero-length string ("")	5	-5	0.5
0	5	-5	1
0.00	5.00	-5.00	0.50
#,##0	5	-5	1
$#,##0;($#,##0)	$5	($5)	$1
$#,##0.00;($#,##0.00)	$5.00	($5.00)	$0.50
0%	500%	-500%	50%
0.00%	500.00%	-500.00%	50.00%
0.00E+00	5.00E+00	-5.00E+00	5.00E-01
0.00E-00	5.00E00	-5.00E00	5.00E-01

Vooraf gedefinieerde datum-/tijdnotaties

In de volgende tabel worden de vooraf gedefinieerde namen van datum- en tijdnotaties geïdentificeerd. Deze kunnen worden gebruikt op naam als het stijlargument voor de Format functie:

Formaatnaam	Beschrijving
General Date, of G	Geeft een datum en/of tijd weer. Bijvoorbeeld: 3/12/2008 11:07:31 AM. De datumweergave wordt bepaald door de huidige cultuurwaarde van uw toepassing.
Long Date, Medium Dateof D	Geeft een datum weer volgens de lange datumnotatie van uw huidige cultuur. Bijvoorbeeld: Wednesday, March 12, 2008.
Short Date, of d	Geeft een datum weer met de korte datumnotatie van uw huidige cultuur. Bijvoorbeeld: 3/12/2008. Het d teken geeft de dag weer in een door de gebruiker gedefinieerde datumnotatie.
Long Time, Medium Timeof T	Geeft een tijd weer met de lange tijdnotatie van uw huidige cultuur; bevat doorgaans uren, minuten, seconden. Bijvoorbeeld: 11:07:31 AM.
Short Time of t	Geeft een tijd weer met de korte tijdnotatie van uw huidige cultuur. Bijvoorbeeld: 11:07 AM. Het t teken geeft AM weer of PM waarden voor landinstellingen die een 12-uurs klok gebruiken in een door de gebruiker gedefinieerde tijdnotatie.
f	Geeft de lange datum en korte tijd weer op basis van de huidige cultuurnotatie. Bijvoorbeeld: Wednesday, March 12, 2008 11:07 AM.
F	Geeft de lange datum en lange tijd weer volgens de huidige cultuurnotatie. Bijvoorbeeld: Wednesday, March 12, 2008 11:07:31 AM.
g	Geeft de korte datum en korte tijd weer op basis van de huidige cultuurnotatie. Bijvoorbeeld: 3/12/2008 11:07 AM.
M, m	Geeft de maand en de dag van een datum weer. Bijvoorbeeld: March 12. Het M teken geeft de maand weer in een door de gebruiker gedefinieerde datumnotatie. Het m teken geeft de minuten weer in een door de gebruiker gedefinieerde tijdnotatie.
R, r	Hiermee wordt de datum opgemaakt op basis van de RFC1123Pattern eigenschap. Bijvoorbeeld: Wed, 12 Mar 2008 11:07:31 GMT. De opgemaakte datum past de waarde van de datum en tijd niet aan. U moet de datum/tijd-waarde aanpassen aan GMT voordat u de Format functie aanroept.
s	Hiermee wordt de datum en tijd opgemaakt als een sorteerbare index. Bijvoorbeeld: 2008-03-12T11:07:31. Het s teken geeft de seconden weer in een door de gebruiker gedefinieerde tijdnotatie.
u	Hiermee wordt de datum en tijd opgemaakt als een sorteerbare GMT-index. Bijvoorbeeld: 2008-03-12 11:07:31Z.
U	Hiermee wordt de datum en tijd opgemaakt met de lange datum en lange tijd als GMT. Bijvoorbeeld: Wednesday, March 12, 2008 6:07:31 PM.
Y, y	Hiermee wordt de datum opgemaakt als het jaar en de maand. Bijvoorbeeld: March, 2008. De Y tekens en y tekens geven het jaar weer in een door de gebruiker gedefinieerde datumnotatie.

Zie How Culture Affects Strings in Visual Basic voor meer informatie over de huidige cultuurinformatie van de toepassing.

datum-/tijdnotaties User-Defined

De volgende tabel bevat tekens die u kunt gebruiken om door de gebruiker gedefinieerde datum-/tijdnotaties te maken. In tegenstelling tot in eerdere versies van Visual Basic zijn deze notatietekens hoofdlettergevoelig.

Teken	Beschrijving
(:)	Tijdscheidingsteken. In sommige landinstellingen kunnen andere tekens worden gebruikt om het tijdscheidingsteken weer te geven. Het tijdscheidingsteken scheidt uren, minuten en seconden wanneer tijdwaarden zijn opgemaakt. Het werkelijke teken dat wordt gebruikt als tijdscheidingsteken in opgemaakte uitvoer, wordt bepaald door de huidige cultuurwaarde van uw toepassing.
(/)	Datumscheidingsteken. In sommige landinstellingen kunnen andere tekens worden gebruikt om het datumscheidingsteken weer te geven. Het datumscheidingsteken scheidt de datum, maand en het jaar waarop datumwaarden zijn opgemaakt. Het werkelijke teken dat wordt gebruikt als het datumscheidingsteken in opgemaakte uitvoer, wordt bepaald door de huidige cultuur van uw toepassing.
(%)	Wordt gebruikt om aan te geven dat het volgende teken moet worden gelezen als een notatie met één letter, zonder rekening te houden met eventuele volgletters. Wordt ook gebruikt om aan te geven dat een notatie met één letter wordt gelezen als een door de gebruiker gedefinieerde indeling. Bekijk wat er volgt voor meer informatie.
d	Geeft de dag weer als een getal zonder voorloopnul (bijvoorbeeld 1). Gebruik %d dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
dd	Geeft de dag weer als een getal met voorloopnul (bijvoorbeeld 01).
ddd	Geeft de dag weer als een afkorting (bijvoorbeeld Sun).
dddd	Geeft de dag weer als een volledige naam (bijvoorbeeld Sunday).
M	Geeft de maand weer als een getal zonder voorloopnul (bijvoorbeeld januari wordt weergegeven als 1). Gebruik %M dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
MM	Geeft de maand weer als een getal met voorloopnul (bijvoorbeeld 01/12/01).
MMM	Geeft de maand weer als een afkorting (bijvoorbeeld Jan).
MMMM	Geeft de maand weer als een volledige maandnaam (bijvoorbeeld January).
gg	Geeft de tekenreeks periode/era weer (bijvoorbeeld A.D.).
h	Geeft het uur weer als een getal zonder voorloopnullen met behulp van de 12-uurs klok (bijvoorbeeld 1:15:15 PM). Gebruik %h dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
hh	Geeft het uur weer als een getal met voorloopnullen met behulp van de 12-uurs klok (bijvoorbeeld 01:15:15 PM).
H	Geeft het uur weer als een getal zonder voorloopnullen met behulp van de 24-uurs klok (bijvoorbeeld 1:15:15). Gebruik %H dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
HH	Geeft het uur weer als een getal met voorloopnullen met behulp van de 24-uurs klok (bijvoorbeeld 01:15:15).
m	Geeft de minuut weer als een getal zonder voorloopnullen (bijvoorbeeld 12:1:15). Gebruik %m dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
mm	Geeft de minuut weer als een getal met voorloopnullen (bijvoorbeeld 12:01:15).
s	Geeft de seconde weer als een getal zonder voorloopnullen (bijvoorbeeld 12:15:5). Gebruik %s dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
ss	Geeft de seconde weer als een getal met voorloopnullen (bijvoorbeeld 12:15:05).
f	Geeft fracties van seconden weer. Geeft bijvoorbeeld ff honderdsten van seconden weer, terwijl ffff tienduizendsten van seconden worden weergegeven. U kunt maximaal zeven f symbolen gebruiken in uw door de gebruiker gedefinieerde indeling. Gebruik %f dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
t	Gebruikt de 12-uurs klok en geeft een hoofdletter A weer voor elk uur vóór de middag; geeft een hoofdletter P weer voor een uur tussen middag en 11:59 uur. Gebruik %t dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
tt	Voor landinstellingen die een 12-uurs klok gebruiken, wordt een hoofdletter AM weergegeven met een willekeurig uur vóór de middag; geeft een hoofdletter PM weer met een willekeurig uur tussen middag en 11:59 uur. Voor landinstellingen die een 24-uurs klok gebruiken, wordt niets weergegeven.
y	Geeft het jaarnummer (0-9) weer zonder voorloopnullen. Gebruik %y dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
yy	Geeft het jaar weer in een numerieke notatie van twee cijfers met een voorloopnul, indien van toepassing.
yyy	Geeft het jaar weer in een numerieke notatie van vier cijfers.
yyyy	Geeft het jaar weer in een numerieke notatie van vier cijfers.
z	Geeft de tijdzoneverschil weer zonder voorloopnul (bijvoorbeeld -8). Gebruik %z dit als dit het enige teken is in uw door de gebruiker gedefinieerde numerieke notatie.
zz	Geeft de tijdzoneverschil weer met een voorloopnul (bijvoorbeeld -08)
zzz	Geeft de offset van de volledige tijdzone weer (bijvoorbeeld -08:00)

Voorbeeld van verouderde code

Hieronder ziet u voorbeelden van door de gebruiker gedefinieerde datum- en tijdnotaties voor December 7, 1958, 8:50 PM, 35 seconds:

Format	Weergaven
M/d/yy	12/7/58
d-MMM	7-Dec
d-MMMM-yy	7-December-58
d MMMM	7 December
MMMM yy	December 58
hh:mm tt	08:50 PM
h:mm:ss t	8:50:35 P
H:mm	20:50
H:mm:ss	20:50:35
M/d/yyyy H:mm	12/7/1958 20:50

Opmerkingen bij ontwikkelaars van slimme apparaten

De minimale tijdsresolutie voor een apparaat wordt bepaald door de fabrikant van het apparaat. Als de tijdomzetting voor het apparaat grof genoeg is, retourneert het f notatieteken 0 wanneer het op dat apparaat wordt uitgevoerd.

Zie ook

• Format(String, Object)
• Str(Object)
• Samenvatting van tekenreeksmanipulatie