DateAndTime.DateSerial(Int32, Int32, Int32) Método

public:
 static DateTime DateSerial(int Year, int Month, int Day);

public static DateTime DateSerial(int Year, int Month, int Day);

static member DateSerial : int * int * int -> DateTime

Public Function DateSerial (Year As Integer, Month As Integer, Day As Integer) As DateTime

Parâmetros

Devoluções

Um valor que representa o ano, mês e dia especificados, com a informação da hora definida para a meia-noite (00:00:00).

Exemplos

Este exemplo utiliza a DateSerial função para devolver a data do ano, mês e dia especificados.

' DateSerial returns the date for a specified year, month, and day.
Dim aDate As Date
' Variable aDate contains the date for February 12, 1969.
aDate = DateSerial(1969, 2, 12)
Console.WriteLine(aDate)

' The following example uses DateSerial to determine and display
' the last day of the previous month.
' First, establish a starting date.
Dim startDate = #1/23/1994#
' The 0 for the day represents the last day of the previous month.
Dim endOfLastMonth = DateSerial(startDate.Year, startDate.Month, 0)
Console.WriteLine("Last day in the previous month: " & endOfLastMonth)

' The following example finds and displays the day of the week that the 
' 15th day of the following month will fall on.
Dim fifteenthsDay = DateSerial(Today.Year, Today.Month + 1, 15)
Console.WriteLine("The 15th of next month is a {0}", fifteenthsDay.DayOfWeek)

Observações

Os valores de dois dígitos para o Year argumento são interpretados com base nas definições do computador definidas pelo utilizador. As definições padrão são que os valores de 0 a 29 são interpretados como os anos de 2000-2029, e os valores de 30 a 99 são interpretados como os anos de 1930-1999. Para indicar todos os outros anos, use um ano de quatro dígitos, por exemplo, 1924.

O exemplo seguinte demonstra valores de argumentos negativos, zero e positivos. Aqui, a DateSerial função devolve a Date representando o dia antes do primeiro dia de março do ano 10 anos antes do ano atual; ou seja, o último dia de fevereiro há dez anos.

Dim EndFeb As Date = DateSerial(-10, 3, 0)

Se algum ou MonthDay exceder o seu intervalo normal, é aplicado à unidade seguinte maior, conforme apropriado. Por exemplo, se especificar 32 dias, é avaliado como um mês e de um a quatro dias, dependendo do valor de Month. Se Year for maior que 9999, ou se algum argumento estiver fora do intervalo -2.147.483.648 a 2.147.483.647, ocorre um ArgumentException erro. Se a data especificada pelos três argumentos for anterior às 00:00:00 de 1 de janeiro do ano 1, ou posterior às 23:59:59 de 31 de dezembro de 9999, ocorre um ArgumentOutOfRangeException erro.

O Date tipo de dados inclui componentes temporais. DateSerial define todas estas para 0, pelo que o valor devolvido representa o início do dia calculado.

Como cada Date valor é suportado por uma DateTime estrutura, os seus métodos dão-lhe opções adicionais para montar um Date valor. Por exemplo, pode usar um dos construtores sobrecarregados DateTime para preencher uma Date variável usando a combinação desejada de componentes. O exemplo seguinte situa-se NewDateTime para 6 de maio de 1978, a um décimo de segundo antes das 8:30 da manhã:

Dim NewDateTime As Date = New Date(1978, 5, 6, 8, 29, 59, 900)

Ver também

• DateValue(String)
• Day(DateTime)
• Month(DateTime)
• Now
• TimeSerial(Int32, Int32, Int32)
• TimeValue(String)
• Weekday(DateTime, FirstDayOfWeek)
• Year(DateTime)
• System
• Resumo do Tipo de Dados (Visual Basic)