ErrObject.Number Propriedade

public:
 property int Number { int get(); void set(int value); };

public int Number { get; set; }

member this.Number : int with get, set

Public Property Number As Integer

Valor de Propriedade

Devolve ou define um valor numérico que especifica um erro. De leitura/escrita.

Exceções

Exemplos

Este exemplo ilustra uma utilização típica da Number propriedade numa rotina de tratamento de erros.

    ' Typical use of Number property.
Sub test()
  On Error GoTo out

  Dim x, y As Integer
  x = 1 / y   ' Create division by zero error.
  Exit Sub
out:
  MsgBox(Err.Number)
  MsgBox(Err.Description)
  ' Check for division by zero error.
  If Err.Number = 11 Then
      y = y + 1
  End If
  Resume Next
End Sub

Este exemplo utiliza o método Raise do objeto Err para gerar um erro original dentro de uma função escrita em Visual Basic. A função de chamada pode detetar o erro e reportá-lo ao utilizador. Note que o procedimento CallingProcedure contrasta o tipo de informação que pode derivar de um Err objeto com a informação que pode derivar de um Exception objeto.

Module Module1

    Const WidthErrorNumber As Integer = 1000
    Const WidthHelpOffset As Object = 100

    Sub Main()
        CallingProcedure()
    End Sub

    Sub TestWidth(ByVal width As Integer)
        If width > 1000 Then
            ' Replace HelpFile.hlp with the full path to an appropriate
            ' help file for the error. Notice that you add the error 
            ' number you want to use to the vbObjectError constant. 
            ' This assures that it will not conflict with a Visual
            ' Basic error.
            Err.Raise(vbObjectError + WidthErrorNumber, "ConsoleApplication1.Module1.TestWidth", 
                "Width must be less than 1000.", "HelpFile.hlp", WidthHelpOffset)
        End If
    End Sub

    Sub CallingProcedure()
        Try
            ' The error is raised in TestWidth.
            TestWidth(2000)
        Catch ex As Exception
            ' The Err object can access a number of pieces of
            ' information about the error.
            Console.WriteLine("Information available from Err object:")
            Console.WriteLine(Err.Number)
            Console.WriteLine(Err.Description)
            Console.WriteLine(Err.Source)
            Console.WriteLine(Err.HelpFile)
            Console.WriteLine(Err.HelpContext)
            Console.WriteLine(Err.GetException)

            Console.WriteLine(vbCrLf & "Information available from Exception object:")
            Console.WriteLine(ex.Message)
            Console.WriteLine(ex.ToString)

            Err.Clear()
        End Try
    End Sub
End Module

' The example produces the following output:
' Information available from Err object:
' -2147220504
' Width must be less than 1000.
' ConsoleApplication1.Module1.TestWidth
' HelpFile.hlp
' 100
' System.Exception: Width must be less than 1000.
'    at Microsoft.VisualBasic.ErrObject.Raise(Int32 Number, Object Source, Object
' Description, Object HelpFile, Object HelpContext)
'    at ConsoleApplication1.Module1.TestWidth(Int32 width) in C:\Users\example\App
' Data\Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 17
'    at ConsoleApplication1.Module1.CallingProcedure() in C:\Users\example\AppData
' \Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 25
'
' Information available from Exception object:
' Width must be less than 1000.
' System.Exception: Width must be less than 1000.
'    at Microsoft.VisualBasic.ErrObject.Raise(Int32 Number, Object Source, Object
' Description, Object HelpFile, Object HelpContext)
'    at ConsoleApplication1.Module1.TestWidth(Int32 width) in C:\Users\example\App
' Data\Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 17
'    at ConsoleApplication1.Module1.CallingProcedure() in C:\Users\example\AppData
' \Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 25

Observações

Todos os Raise argumentos, exceto Number os opcionais, são opcionais. Se omitir argumentos opcionais, e as definições de propriedades do Err objeto conterem valores que não foram eliminados, esses valores servem como valores para o seu erro.

Como o Err objeto fornece informação mais rica do que quando gera erros com a Error instrução, Raise é útil para gerar erros ao escrever módulos de classe. Por exemplo, com o Raise método, a fonte que gerou o erro pode ser especificada na Source propriedade, a Ajuda online para o erro pode ser referenciada, e assim sucessivamente.

Ao devolver um erro definido pelo utilizador a partir de um objeto, define Err.Number adicionando o número selecionado como código de erro à VbObjectError constante. Por exemplo, usa o seguinte código para devolver o número 1051 como código de erro:

Err.Raise(Number:=vbObjectError + 1051, Source:="SomeClass")

Ver também

• Err()
• ErrorToString()