FileSystem.WriteLine(Int32, Object[]) Método

Definição

Espaço de Nomes:
Microsoft.VisualBasic
Assemblagem:
Microsoft.VisualBasic.dll

Escreve dados num ficheiro sequencial. Os dados escritos com Write são geralmente lidos de um ficheiro usando Input.

public:
 static void WriteLine(int FileNumber, ... cli::array <System::Object ^> ^ Output);
public static void WriteLine(int FileNumber, params object[] Output);
static member WriteLine : int * obj[] -> unit
Public Sub WriteLine (FileNumber As Integer, ParamArray Output As Object())

Parâmetros

FileNumber
Int32

Required. Uma Integer expressão que contém qualquer número de ficheiro válido.

Output
Object[]

Optional. Uma ou mais expressões delimitadas por vírgulas para escrever num ficheiro.

Exemplos

Este exemplo utiliza a Write função para escrever dados brutos num ficheiro sequencial.

' Open file for output.
FileOpen(1, "TestFile.txt", OpenMode.Output)
' Print text to the file. The quotation marks will be in the display.
Write(1, "This is a test.")
' Go to the next line.
WriteLine(1)
' Skip a line.
WriteLine(1)
' Print in two print zones. You will see commas and quotation marks
' in the output file.
WriteLine(1, "Zone 1", SPC(10), "Zone 2")
' Build a longer string before calling WriteLine.
WriteLine(1, "Hello" & "  " & "World")
' Include five leading spaces.
WriteLine(1, SPC(5), "Leading spaces")
' Print a word starting at column 10.
WriteLine(1, TAB(10), "Hello")

' Assign Boolean and Date values.
Dim aBool As Boolean
Dim aDate As DateTime
aBool = False
aDate = DateTime.Parse("February 12, 1969")

' Dates and Booleans are translated using locale settings of 
' your system.
WriteLine(1, aBool & " is a Boolean value.")
WriteLine(1, aDate & " is a date.")
' Close the file.
FileClose(1)

' Contents of TestFile.txt
'"This is a test.",
'
'"Zone 1",          "Zone 2"
'"Hello  World"
'     "Leading spaces"
'         ,"Hello"
'"False is a Boolean value."
'"2/12/1969 is a date."

Observações

As Write funções e WriteLine são fornecidas para compatibilidade retroativa e podem afetar o desempenho. Para aplicações não legadas, o My.Computer.FileSystem objeto oferece melhor desempenho. Para mais informações, consulte Acesso a ficheiros com Visual Basic.

Se omitires Output, uma linha em branco é impressa no ficheiro. Múltiplas expressões podem ser separadas por uma vírgula.

Ao contrário da Print função, esta Write insere vírgulas entre os itens e aspas em torno das cadeias à medida que são escritas no ficheiro. Não tens de colocar delimitadores explícitos na lista. Quando Write é usado para escrever dados num ficheiro, apenas são suportados os formatos numérico, Boolean, data, nulo e Error de dados. Seguem-se as seguintes suposições universais para que os dados possam sempre ser lidos e corretamente interpretados usando Input, independentemente da localização:

  • Os dados numéricos são sempre escritos usando o ponto como separador decimal.

  • Para dados Boolean , qualquer #TRUE# um ou #FALSE# é impresso. As True palavras-chave e False não são traduzidas, independentemente da localização.

  • Os dados de data são escritos no ficheiro usando o formato universal de data. Quando a data ou a hora estão em falta ou são zero, apenas a parte fornecida é escrita no ficheiro.

  • Nada é escrito no ficheiro se Output os dados estiverem vazios. No entanto, para dados nulos, #NULL# é escrito.

  • Para Error dados, a saída aparece como #ERROR errorcode#. A Error palavra-chave não é traduzida, independentemente da localização.

WriteLine insere um carácter de nova linha (ou seja, um retorno de carroça/avanço de linha, ou Chr(13) + Chr(10)), depois de ter escrito o último carácter Output no ficheiro.

Pode inserir aspas numa sequência usando aspas duplas, ou "". Por exemplo

Dim x As String = "Double quotation marks aren't ""difficult"" to handle."

devolve uma cadeia com o valor de Double quotation marks aren't "difficult" to handle.

Escrever num ficheiro usando as Write funções ou WriteLine requer Append acesso a partir da FileIOPermissionAccess enumeração. Para obter mais informações, consulte FileIOPermissionAccess .

Aplica-se a

Ver também