Interaction.MsgBox(Object, MsgBoxStyle, Object) Método

Definição

Espaço de Nomes:
Microsoft.VisualBasic
Assemblagem:
Microsoft.VisualBasic.dll

Apresenta uma mensagem numa caixa de diálogo, espera que o utilizador clique num botão e depois devolve um inteiro que indica qual botão o utilizador clicou.

public static Microsoft.VisualBasic.MsgBoxResult MsgBox(object Prompt, Microsoft.VisualBasic.MsgBoxStyle Buttons = Microsoft.VisualBasic.MsgBoxStyle.ApplicationModal, object Title = default);
static member MsgBox : obj * Microsoft.VisualBasic.MsgBoxStyle * obj -> Microsoft.VisualBasic.MsgBoxResult
Public Function MsgBox (Prompt As Object, Optional Buttons As MsgBoxStyle = Microsoft.VisualBasic.MsgBoxStyle.ApplicationModal, Optional Title As Object = Nothing) As MsgBoxResult

Parâmetros

Prompt
Object

Required. String Expressão apresentada como a mensagem na caixa de diálogo. O comprimento máximo de Prompt é aproximadamente 1024 caracteres, dependendo da largura dos caracteres utilizados. Se Prompt for composta por mais do que uma linha, pode separar as linhas usando um carácter de retorno de carro (Chr(13)), um carácter de retorno de linha (Chr(10)) ou uma combinação de caracteres de retorno de carroça/avanço de linha (Chr(13) e Chr(10)) entre cada linha.

Buttons
MsgBoxStyle

Optional. Expressão numérica que é a soma de valores que especificam o número e tipo de botões a mostrar, o estilo de ícone a usar, a identidade do botão padrão e a modalidade da caixa de mensagem. Se omitires Buttons, o valor padrão é zero.

Title
Object

Optional. String expressão mostrada na barra de título da caixa de diálogo. Se omitir Title, o nome da candidatura aparece na barra de título.

Devoluções

MsgBoxResult

Um dos seguintes valores:

ConstanteValor
OK1
Cancel2
Abort3
Retry4
Ignore5
Yes6
No7

Exceções

ArgumentException

Prompt não é uma String expressão, ou Title é inválida.

InvalidOperationException

O processo não está a correr em modo Interativo do Utilizador.

InvalidEnumArgumentException

Um ou mais parâmetros que não são membros de MsgBoxResult ou MsgBoxStyle enumeração.

Exemplos

Este exemplo utiliza a MsgBox função para mostrar uma mensagem de erro crítico numa caixa de diálogo com botões Sim e Não. O botão Não é especificado como a resposta predefinida. Isto é feito combinando os MsgBox valores constantes numa única expressão numérica. Neste caso, adicionar 4 (a combinação de botões Sim/Não), 16 (a janela de Mensagem Crítica ) e 256 (o segundo botão como botão padrão) dá um total de 276. O valor devolvido pela MsgBox função depende do botão escolhido pelo utilizador: Sim devolve um valor de 6; Sem retornos, um valor de 7.

' The following example requires that Option Infer be set to On.

' Define the message you want to see inside the message box.
Dim msg = "Do you want to continue?"

' Display a simple message box.
MsgBox(msg)

' Define a title for the message box.
Dim title = "MsgBox Demonstration"

' Add the title to the display.
MsgBox(msg, , title)

' Now define a style for the message box. In this example, the
' message box will have Yes and No buttons, the default will be
' the No button, and a Critical Message icon will be present.
Dim style = MsgBoxStyle.YesNo Or MsgBoxStyle.DefaultButton2 Or
            MsgBoxStyle.Critical

' Display the message box and save the response, Yes or No.
Dim response = MsgBox(msg, style, title)

' Take some action based on the response.
If response = MsgBoxResult.Yes Then
    MsgBox("YES, continue!!", , title)
Else
    MsgBox("NO, stop!!", , title)
End If

Observações

Se omitir quaisquer argumentos posicionais, deve manter o correspondente delimitador de vírgula.

Se a caixa de diálogo mostrar um botão Cancelar , pressionar a tecla ESC tem o mesmo efeito que clicar em Cancelar

Se a caixa de diálogo contiver um botão Ajuda , a Ajuda sensível ao contexto é fornecida para a caixa de diálogo. No entanto, nenhum valor é devolvido até que um dos outros botões seja escolhido. Nas aplicações Windows Formulário, escolher o botão Ajuda executa o evento HelpRequested para o formulário.

Note

A MsgBox função requer UIPermission ao SafeTopLevelWindows nível, o que pode afetar a sua execução em situações de confiança parcial. Para obter mais informações, veja UIPermission.

Os MsgBoxStyle valores de enumeração estão listados na tabela seguinte.

Membro Valor Description
Membro Valor Description
OKOnly 0 Mostra apenas o botão OK.
OKCancel 1 Exibe os botões OK e Cancelar.
AbortRetryIgnore 2 Exibe os botões de Abortar, Retentar e Ignorar.
YesNoCancel 3 Mostra os botões Sim, Não e Cancelar.
YesNo 4 Exibe botões de Sim e Não.
RetryCancel 5 Mostra os botões de Retentar e Cancelar.
Critical 16 Mostra o ícone de Mensagem Crítica.
Question 32 Mostra o ícone de Consulta de Aviso.
Exclamation 48 Mostra o ícone de Mensagem de Aviso.
Information 64 Mostra o ícone da Mensagem de Informação.
DefaultButton1 0 O primeiro botão é predefinido.
DefaultButton2 256 O segundo botão é predefinido.
DefaultButton3 512 O terceiro botão é predefinido.
ApplicationModal 0 A aplicação é modal. O utilizador deve responder à caixa de mensagens antes de continuar a trabalhar na aplicação atual.
SystemModal 4096 O sistema é modal. Todos os aplicativos são suspensos até que o usuário responda à caixa de mensagem.
MsgBoxSetForeground 65536 Especifica a janela da caixa de mensagem como janela em primeiro plano.
MsgBoxRight 524288 O texto está alinhado à direita.
MsgBoxRtlReading 1048576 Especifica que o texto deve aparecer como leitura da direita para a esquerda nos sistemas hebraico e árabe.

O primeiro grupo de valores (0-5) descreve o número e tipo de botões apresentados na caixa de diálogo. O segundo grupo (16, 32, 48, 64) descreve o estilo dos ícones. O terceiro grupo (0, 256, 512) determina qual botão é o padrão. O quarto grupo (0, 4096) determina a modalidade da caixa de mensagem, e o quinto grupo especifica se a janela da caixa de mensagens é ou não a janela em primeiro plano, juntamente com o alinhamento e direção do texto. Ao somar números para criar um valor final para o Buttons argumento, use apenas um número de cada grupo.

Aplica-se a

Ver também