ErrObject.Number 屬性

public:
 property int Number { int get(); void set(int value); };

public int Number { get; set; }

member this.Number : int with get, set

Public Property Number As Integer

屬性值

回傳或設定一個數值以指定錯誤。 讀/寫。

例外狀況

範例

此範例說明了該 Number 特性在錯誤處理例程中的典型應用。

    ' Typical use of Number property.
Sub test()
  On Error GoTo out

  Dim x, y As Integer
  x = 1 / y   ' Create division by zero error.
  Exit Sub
out:
  MsgBox(Err.Number)
  MsgBox(Err.Description)
  ' Check for division by zero error.
  If Err.Number = 11 Then
      y = y + 1
  End If
  Resume Next
End Sub

此範例使用 Err 物件的 Raise 方法，在 Visual Basic 中撰寫的函式中產生原始錯誤。 呼叫函式可以偵測錯誤並回報給使用者。 請注意，程序 CallingProcedure 對比了你從物件中能推導 Err 出的資訊類型，與從物件中可獲得 Exception 的資訊類型。

Module Module1

    Const WidthErrorNumber As Integer = 1000
    Const WidthHelpOffset As Object = 100

    Sub Main()
        CallingProcedure()
    End Sub

    Sub TestWidth(ByVal width As Integer)
        If width > 1000 Then
            ' Replace HelpFile.hlp with the full path to an appropriate
            ' help file for the error. Notice that you add the error 
            ' number you want to use to the vbObjectError constant. 
            ' This assures that it will not conflict with a Visual
            ' Basic error.
            Err.Raise(vbObjectError + WidthErrorNumber, "ConsoleApplication1.Module1.TestWidth", 
                "Width must be less than 1000.", "HelpFile.hlp", WidthHelpOffset)
        End If
    End Sub

    Sub CallingProcedure()
        Try
            ' The error is raised in TestWidth.
            TestWidth(2000)
        Catch ex As Exception
            ' The Err object can access a number of pieces of
            ' information about the error.
            Console.WriteLine("Information available from Err object:")
            Console.WriteLine(Err.Number)
            Console.WriteLine(Err.Description)
            Console.WriteLine(Err.Source)
            Console.WriteLine(Err.HelpFile)
            Console.WriteLine(Err.HelpContext)
            Console.WriteLine(Err.GetException)

            Console.WriteLine(vbCrLf & "Information available from Exception object:")
            Console.WriteLine(ex.Message)
            Console.WriteLine(ex.ToString)

            Err.Clear()
        End Try
    End Sub
End Module

' The example produces the following output:
' Information available from Err object:
' -2147220504
' Width must be less than 1000.
' ConsoleApplication1.Module1.TestWidth
' HelpFile.hlp
' 100
' System.Exception: Width must be less than 1000.
'    at Microsoft.VisualBasic.ErrObject.Raise(Int32 Number, Object Source, Object
' Description, Object HelpFile, Object HelpContext)
'    at ConsoleApplication1.Module1.TestWidth(Int32 width) in C:\Users\example\App
' Data\Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 17
'    at ConsoleApplication1.Module1.CallingProcedure() in C:\Users\example\AppData
' \Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 25
'
' Information available from Exception object:
' Width must be less than 1000.
' System.Exception: Width must be less than 1000.
'    at Microsoft.VisualBasic.ErrObject.Raise(Int32 Number, Object Source, Object
' Description, Object HelpFile, Object HelpContext)
'    at ConsoleApplication1.Module1.TestWidth(Int32 width) in C:\Users\example\App
' Data\Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 17
'    at ConsoleApplication1.Module1.CallingProcedure() in C:\Users\example\AppData
' \Local\Temporary Projects\ConsoleApplication1\Module1.vb:line 25

備註

除了Number所有參數外，其他都是Raise可選的。 如果你省略了可選參數，且物件的屬性設定 Err 中包含未清除的值，這些值就成為你錯誤的值。

因為這個 Err 物件提供的資訊比用 Error 陳述句產生錯誤更豐富，這 Raise 對於撰寫類別模組時產生錯誤非常有用。 例如，使用該 Raise 方法，可以在屬性中指定 Source 產生錯誤的來源，並參考錯誤的線上說明，等等。

當從物件回傳使用者定義的錯誤時， Err.Number 會將你選擇的錯誤碼數字加到 VbObjectError 常數中。 例如，你使用以下代碼來回傳數字 1051 作為錯誤代碼：

Err.Raise(Number:=vbObjectError + 1051, Source:="SomeClass")

另請參閱

• Err()
• ErrorToString()